Re: [ferret_users] sticking noaxes ?

["William S. Kessler" <William.S.Kessler@xxxxxxxx>]

I had never heard of /NOAXES, but this effect is easy enough to turn  
on and off with the command

PPL AXSET,top,bottom,left,right    ! 1 to draw the axis, 0 to omit

The on/off state of each axis persists until changed by another PPL  
AXSET statement.

Billy K

On Mar 4, 2009, at 5:15 PM, Ryo Furue wrote:

> Hi Ferreters,
>
> It seems that the NOAXES qualifier sometimes "sticks":
>
>    ! first panel
>    set view left_panel
>    . . .
>    plot/noaxes/ . . . var
>
>    ! second panel
>    set view right_panel
>    plot var
>
> and then, sometimes, the second panel doesn't have axes.
> I don't think this is an intended behavior.
>
> I've attached an example.  I tried to reduce the example further,
> but those reductions I tried restored the axes of the second panel.
>
> Regards,
> Ryo
> \cancel mode verify
> cancel mode grat
>
> !------
> define symbol xw_ 0
> define symbol xe_ 90
> define symbol ys_ -60
> define symbol yn_ 0
>
> define symbol reg_ hlimits=($xw_):($xe_):10/vlimits=($ys_):($yn_):10
>
> !---------
> define symbol hei_ 0.3
> define symbol wid_ `($hei_)*3/2`
> define symbol xskip_ 0.05
> define symbol wid_wind_ 0.15
> define symbol xv0_ 0.2
> define symbol yv0_ 0.2
>
> define symbol xv1_ `($xv0_) + ($wid_)`
> define symbol yv1_ `($yv0_) + ($hei_)`
>
> define symbol xv2_ `($xv1_) + ($xskip_)`
> define symbol xv3_ `($xv2_) + ($wid_wind_)`
>
> define view/axes/x=($xv0_),($xv1_)/y=($yv0_),($yv1_)  ocean
>
> define view/axes/x=($xv2_),($xv3_)/y=($yv0_),($yv1_)  wind
>
> !-----------
> set data levitus_climatology
>
> set view ocean
>
> contour/($reg_)/k=1/l=1/nolabel temp
> contour/($reg_)/k=1/l=1/color=black/lev=1D/noaxes/nolabel/ov/set temp
>   ppl conset,0
> ppl contour/ov
>
> !#######
> plot/vs/dash/thick=3/nolabel/noaxes/ov {($xw_), ($xe_)}, {($y1_),  
> ($y1_)}
> !plot/vs/dash/thick=3/nolabel/ov {($xw_), ($xe_)}, {($y1_), ($y1_)}
>
>
> !----------
> set view wind
> contour/k=1/l=1 temp
>
> set mode/last grat
> set mode/last verify
> <noaxes.gif>