Hi Peng,
This is a bug.
I looked more closely at the commands you're using, and did some
experiments of my own, and it seems that the /VLIM=40:0:2 which you
have used to reverse the vertical axis is what is causing the SHADE
command in gif mode to go wrong. I think this goes all the way back to
2003, when we implemented a new method of drawing SHADE plots in gif
mode
(http://ferret.pmel.noaa.gov/FERRET_17sep07/Documentation/Release_Notes/v553.html#cellarray)
.
ferret -gif
yes? shade/i=1:40/j=1:40/vlim=40:0:2 i+j
yes? frame/file=xx.gif
the output shows what you reported - a blank rectangle and a colorbar.
In the meantime, while we work on this, a workaround is to draw the
plot a second time; an overlay plot is not done with the cellarray call
that's used for gif mode.
ferret -gif
yes? shade/i=1:40/j=1:40/vlim=40:0:2 i+j
yes? shade/overlay/nolabel/i=1:40/j=1:40/vlim=40:0:2 i+j
yes? frame/file=xx.gif
Ansley
Ge Peng wrote:
Hi Peng,
We need more information to find out what's happening. If possible,
could you construct an example of the problem that uses data that's part
of the Ferret distribution, or is available via opendap? Also, what
version of Ferret are you running and on what platform? If you run
Ferret in standard, non-gif mode, are the image files by
frame/file=name.gif correct?
Ansley
Hi Ansley,
Thanks for your reply.
I am running ferret v6 on unix:
% ferret
NOAA/PMEL TMAP
FERRET v6
Linux(g77) 2.4.21-32 - 08/23/06
8-Sep-08 14:00
yes?
The image files by frame/file=name.gif are actually correct when running
Ferret in standard, non-gif mode.
This is very interesting as in the past, I seem to have more problems when
trying to generate gif files in the non-gif mode.
--- Peng
Ge Peng wrote:
Hi, I am trying to create gif files using the ferret script at the
bottom
of this message. Figures looked fine in the normal ferret mode on my
computer screen with frame commands commented out. However, I only got
picture frames without color filled contours in the gif files using
ferret
-gif (see the attached fig).
Does any one know what is going on?
Thanks a lot,
--- Peng
----------------------------------------
cancel data/all
cancel sym/all
cancel region/all
define symb dpath_in=/seal1/gpeng/mom4_trip_sim/dta/dynamicMode
define symb runid=temp_anom_jmax_check_mom4_trip
define symb runid2=salt_anom_jmax_check_mom4_trip
define symb dpath_out=/seal1/gpeng/mom4_trip_sim/fig/dynamicMode
use "($dpath_in)/ts_kmu_check_mom4_trip.nc"
set region/j=410
sp rm -f ($dpath_out)/($runid).gif
sp rm -f ($dpath_out)/($runid2).gif
let ocean_t = if (temp_t gt -99.9) then 1 else 0
let ocean_u = if (temp_u gt -99.9) then 1 else 0
let temp_t_ocn = temp_t*ocean_t
let temp_t_anom =temp_t_ocn - temp_t_ocn[i=@ave]
let temp_u_ocn = temp_u*ocean_u
let temp_u_anom =temp_u_ocn - temp_u_ocn[i=@ave]
let salt_t_ocn = salt_t*ocean_t
let salt_t_anom =salt_t_ocn - salt_t_ocn[i=@ave]
let salt_u_ocn = salt_u*ocean_u
let salt_u_anom =salt_u_ocn - salt_u_ocn[i=@ave]
cancel viewport ul ll ur lr
define viewport/xlimits=0.03,0.49/ylim=0.53,0.97 ul
define viewport/xlimits=0.03,0.49/ylim=0.03,0.49 ll
define viewport/xlimits=0.53,0.97/ylim=0.53,0.97 ur
define viewport/xlimits=0.53,0.97/ylim=0.03,0.49 lr
set viewport ul
shad/vlimits=40:0:2 temp_t_ocn
set viewport ur
shad/vlimits=40:0:2 temp_u_ocn
set viewport ll
shad/vlimits=40:0:2 temp_t_anom
set viewport lr
shad/vlimits=40:0:2 temp_u_anom
frame/file="($dpath_out)/($runid).gif"
cancel viewport ul ll ur lr
define viewport/xlimits=0.03,0.49/ylim=0.53,0.97 ul
define viewport/xlimits=0.03,0.49/ylim=0.03,0.49 ll
define viewport/xlimits=0.53,0.97/ylim=0.53,0.97 ur
define viewport/xlimits=0.53,0.97/ylim=0.03,0.49 lr
set viewport ul
shad/vlimits=40:0:2 salt_t_ocn
set viewport ur
shad/vlimits=40:0:2 salt_u_ocn
set viewport ll
shad/vlimits=40:0:2 salt_t_anom
set viewport lr
shad/vlimits=40:0:2 salt_u_anom
frame/file="($dpath_out)/($runid2).gif"
------------------------------------------------------------------------
|