Re: [ferret_users] shade: a cross section with the surface topographyfilled at the bottom?

[Jaison Kurian <jaison@xxxxxxxxxxxxxxxxxx>]

Hi Emilie,
           Here are 3 methods to solve your problem. 

Also have a look at 

http://www.ferret.noaa.gov/Ferret/Mail_Archives/fu_98/msg00242.html
http://ferret.wrc.noaa.gov/Ferret/Mail_Archives/fu_2000/msg00083.html

And see : ferret/examples/two_dee_plot_of_1d.jnl

Plese have a trial with the example below,

Hope this helps,

Jaison

!---------------------------------------------------------------------
\ cancel mode verify
!
! 3 methods to overlay bottom topography on vertical section plots
!
!-------------------------------------------------------------------
!
!--1. THE BEST ONE : from ferret/examples/two_dee_plot_of_1d.jnl
!         Please note that the topography is not in the data resolution

   set data etopo20
   set data levitus_climatology
   set region/x=180:360/y=20n/z=0:5000
   let bottom = (-1)*rose[d=etopo20]
   let bottom_2d = bottom - z[g=temp]
   fill temp[x=@fln:100]
   fill/over/lev=(-10000)(0)/palette=black/nolab bottom_2d

   pause

!--2. Simple one, bit ugly, works good only with SHADE command.
!        Here the topography is in the resolution of the data.
!        Trick : define a variable which is valid where temperature
!                 is missing, then overlay this variable.

   let topo = IF temp THEN (`temp,r=bad`) ELSE 1
   shade temp
   shade/ov/nolab/nokey/pal=black topo

   pause

!--3. Better method than 2, both SHADE and FILL works fine.
!        Here the topography is in the resolution of the data.
!        Trick : Fill the plot area with a color (define a variable
!                 with the same grid as temperature but with the 
!                 value 1 EVERYWHERE, use this variable to fill). 
!                 Then fill or shade temperature over this.
!    This method will also work in one (default) view port, with 
!      "/overlay" as in 2 above. But sometime it may lead to 
!      problems with color key and "/set" & "ppl fill".

   define view/xlim=0:1/ylim=0:1 v1
   define view/xlim=0:1/ylim=0:1 v2
   set reg/x=180:360/y=20n/z=0:5000
   let topo = IF temp THEN 1 ELSE 1
   set view v1
     shade/pal=black/nolab/nokey/noaxes topo
   set view v2
     fill temp
!---------------------------------------------------------------------

On Fri, 29 Sep 2006, Emilie Vanvyve wrote:

> Dear Ferret users,
> 
> I looked at the online help, found some clues to help me, but I  
> haven't succeeded so far and thought of submitting my question to you.
> 
> I plot a cross section of the zonal wind with a simple "shade/x=0/l=1/ 
> vlimit=1000:0:-100 uairdy,lat,pressure". The resulting graph is  
> joined to this email.
> How can I get the imitation of the surface topography (the white  
> area) shaded in grey or black or whatever colour?
> 
> In the sigma_coordinate_demo.jnl script, some similar graphs are made  
> and obviously succeeded where I fail. But the problem is taken  
> backwards: first the topography is defined (variable "bathymetry"),  
> then the variable is computed, then the variable is plotted, then the  
> bathymetry is overlayed.
> How can I compute the surface topography from my data? I can get the  
> value of the pressure at the surface, but I haven't succeeded to make  
> it 3D "under the surface" and even less to plot it nicely.
> 
> Would anybody know how to do?
> 
> Many thanks in advance,
> 
> Emilie
> 
>