Re: [ferret_users] different time axis

[Jaison Kurian <jaison@xxxxxxxxxxxxxxxxxx>]

Hi Seon Tae,
              From Ferret documentation, "@ASN Associates by subscript
(blindly) the points from the source grid onto destination coordinates."
Hence u[d=2,gt=ssta@asn] will give you only 12 valid points in the
resulting time axis. The proper way to extend a climatology onto
another time axis (i mean observation/model with non-climatological
time axis) the proper way is to

   1. Check the time axis of the climatology variable is "MODULO".
        If it is not, then set it to MODULO.

   2. Now just assign the destination time axis to this climatology
        variable as follows

         u[d=2,gt=ssta]

Be carefull with "set reg" command for time in the jnl file. You may
need a "cancel reg/all" command at the beginning/end of the jnl file.

You may proceed as explained below. If you face any problem, mail
back with the output of "ncdump -h" for both the files.

Regards

Jaison

!-----------------------------------------------------------------
! Assuming both datasets are on calendar (monthly) time axis.

     use dataset1.nc ! file containing ssta
     use dataset2.nc ! file containing u

! now check wether the time axis is modulo. For example if you
!   use coads climatology, "yes? show grid sst" will give you
!
!         name   axis    # pts   start            end
!
!         TIME   TIME    12mr    16-JAN  06:00    16-DEC  01:20
!
!   this "m" with 12mr in the third column shows the the time axis
!   io "MODULO"

     show grid u[d=2] ! check wether time axis is modulo

! if time axis is not modulo then

     set axis/modulo time_axis_name

! now extend the climatology to the time axis of anomaly during
!   the calculation as follows

     let dtdx      = ssta[d=1,x=@ddc]     !  100year-anomalous sst
     let area_dtdx = dtdx[x=160w:95w@ave,y=-2:2@ave]
     let ubar      = u[d=2,x=160w:95w@ave,y=-2:2@ave,gt=ssta]
     plot ubar*area_dtdx

!-----------------------------------------------------------------

On Wed, 15 Feb 2006, Seon Tae wrote:

> Hi all...
> I have monthly mean climatology data and 100 year-anomaly data which have 
> different time axis each.
> I trid to plot time series of the product of climatology and anomaly.
>
> When I do like the following
>
> let dtdx = ssta[d=1,x=@ddc] !100year-anomalous sst
> let area_dtdx = dtdx[x=160w:95w@ave,y=-2:2@ave]
> let ubar = u[d=2,x=160w:95w@ave,y=-2:2@ave,gt=ssta@asn]
> plot ubar*area_dtdx
>
> I used '@asn' for extending time coverage of climatology data to 100 year.
> I guessed that seasonal cycle of the climatology would repeat 100 times after 
> regriding
> but it did not happen.
>
> Only a curve  for 12 month of the first year showed up.
>
> i think what i did is not right.
>
> I hope you guys understand my question.
>
> Thank you very much  in advance